Управление трактором с помощью джойстика

[Resin]

@Resin

// пин светодиода
const uint8_t Led = 13;

// пины осей джойстика
const uint8_t pin_joyX = A0; // пин оси Х джойстика
const uint8_t pin_joyY = A1; // пин оси Y джойстика
const uint8_t pin_joyZ = A2; // пин оси Z джойстика
// пины клапанов
const uint8_t pin_valweFL =  9; // пин электромагнита A (вперед левая)
const uint8_t pin_valweFR = 10; // пин электромагнита B (вперед правая)
const uint8_t pin_valweBL = 11; // пин электромагнита C (назад левая)
const uint8_t pin_valweBR = 12; // пин электромагнита D (назад правая)

// это калибровки джойстика (минимум, центр, максимум), они для каждой оси могут быть разные
// можете замерить 1 раз и вписать в программу, можете потом всетаки реализоввать калибровку, как я очень советую
// ВАЖНО пишем реальное значение "до упора"
// Если "до упора вперед" это 600, а "до упора назад" это 200 то так и пишем, по возрастанию не сортируем!
int16_t   joyX_F_max = 390; // X до упора вперед
int16_t     joyX_mid = 510; // X центр
int16_t   joyX_B_max = 630; // X до упора назад
int16_t   joyY_L_max = 340; // Y до упора влево
int16_t     joyY_mid = 500; // Y центр
int16_t   joyY_R_max = 611; // Y до упора вправо
int16_t  joyZ_CW_max = 340; // Z до упора по часовой
int16_t     joyZ_mid = 500; // Z центр
int16_t joyZ_CCW_max = 611; // Z до упора против часовой

// это отклонения джойстика от центра, которые будут игнорироваться (называется death zone - мертвая зона)
// нужно чтобы избегать нежелательные срабатывания когда сенсоры джойстика немного "поплывут"
// от разницы температуры или изменения окружающего магнитного поля
const uint8_t joy_dz = 10;

// вычисляем начало интервалов для каждой оси, с учетом калибровки центров и мертвой зоны
// эта часть вычислит правильно независимо от того, в цифрах joyX_F_max больше или меньше чем joyX_B_max (и так же для остальных осей)
int16_t   joyX_F_min =   joyX_F_max > joyX_mid ? joyX_mid + joy_dz : joyX_mid - joy_dz;
int16_t   joyX_B_min =   joyX_B_max > joyX_mid ? joyX_mid + joy_dz : joyX_mid - joy_dz;
int16_t   joyY_L_min =   joyY_L_max > joyY_mid ? joyY_mid + joy_dz : joyY_mid - joy_dz;
int16_t   joyY_R_min =   joyY_R_max > joyY_mid ? joyY_mid + joy_dz : joyY_mid - joy_dz;
int16_t  joyZ_CW_min =  joyZ_CW_max > joyZ_mid ? joyZ_mid + joy_dz : joyZ_mid - joy_dz;
int16_t joyZ_CCW_min = joyZ_CCW_max > joyZ_mid ? joyZ_mid + joy_dz : joyZ_mid - joy_dz;



void setup() {

  pinMode(Led, OUTPUT);
  pinMode(pin_valweFL, OUTPUT);
  pinMode(pin_valweFR, OUTPUT);
  pinMode(pin_valweBL, OUTPUT);
  pinMode(pin_valweBR, OUTPUT);
  
  Serial.begin(9600);
  
}



void loop() {

  // это мы получаем "сырые" показания с датчиков холла (оси джойстика) как есть
  int16_t joy_X = analogRead(pin_joyX);
  int16_t joy_Y = analogRead(pin_joyY);
  int16_t joy_Z = analogRead(pin_joyZ);
  
  // нормализуем значения
  // функция map() нам пропорционально приведет занчение с холла из интервала joyX_F_min..joyX_F_max к интервалу 0..255
  // но эта функция позволяет выходить за рамки интервала, если joy_X не лежит в пределах joyX_F_min..joyX_F_max
  // и получится значение за пределами интервала 0..255
  // поэтому используем функцию constrain(), которая обрежет результат выполнения map() до нужных 0..255
  int16_t          forward = constrain(map(joy_X,   joyX_F_min,   joyX_F_max, 0, 255), 0, 255); // полуось джойстика "вперед"
  int16_t         backward = constrain(map(joy_X,   joyX_B_min,   joyX_B_max, 0, 255), 0, 255); // полуось джойстика "назад"
  int16_t             left = constrain(map(joy_Y,   joyY_L_min,   joyY_L_max, 0, 255), 0, 255); // полуось джойстика "влево"
  int16_t            right = constrain(map(joy_Y,   joyY_R_min,   joyY_R_max, 0, 255), 0, 255); // полуось джойстика "вправо"
  int16_t        clockwise = constrain(map(joy_Z,  joyZ_CW_min,  joyZ_CW_max, 0, 255), 0, 255); // полуось джойстика "по часовой"
  int16_t counterclockwise = constrain(map(joy_Z, joyZ_CCW_min, joyZ_CCW_max, 0, 255), 0, 255); // полуось джойстика "против часовой"
  
//  /* для отладки выведем в порт значения
  Serial.println("forward: " + String(forward) +
              ", backward: " + String(backward) +
                  ", left: " + String(left) +
                 ", right: " + String(right) +
             ", clockwise: " + String(clockwise) +
      ", counterclockwise: " + String(counterclockwise));/**/
  
  // теперь у вас нормализованные значения 0..255, на их основе можно вычислить степень открытости клапанов
  // причем по одной оси только одно значение сможет быть больше нуля, если джойстик вообще был отклонен
  
  // значения для клапанов
  int16_t valweFL = 0; // электромагнит A (вперед левая)
  int16_t valweFR = 0; // электромагнит B (вперед правая)
  int16_t valweBL = 0; // электромагнит C (назад левая)
  int16_t valweBR = 0; // электромагнит D (назад правая)
  
  if (forward > 0 || backward > 0) {
    // есть движение вперед или назад, повороты замедлением одной стороны
    valweFL = constrain( forward -  left, 0, 255);
    valweFR = constrain( forward - right, 0, 255);
    valweBL = constrain(backward -  left, 0, 255);
    valweBR = constrain(backward - right, 0, 255);
  } else {
    // нет движения вперед или назад, делаем разворот
    valweFL = clockwise;
    valweFR = counterclockwise;
    valweBL = counterclockwise;
    valweBR = clockwise;                 
  }
  
  // выводим ШИМ
  analogWrite(pin_valweFL, valweFL);
  analogWrite(pin_valweFR, valweFR);
  analogWrite(pin_valweBL, valweBL);
  analogWrite(pin_valweBR, valweBR);
    
//  /* для отладки выведем в порт значения
  Serial.println("valweFL: " + String(valweFL) +
               ", valweFR: " + String(valweFR) +
               ", valweBL: " + String(valweBL) +
               ", valweBR: " + String(valweBR));/**/

}

короче грузите этот, скопируйте еще раз, я его пару раз редактировал. но больше не буду

Если чето не то будет выдавать - пишите, покумекаем…

П.с. в коде заложено небольшое “пространство для маневра” - если надо будет ограничить резкость по какой-то из осей управления, это без особых проблем можно будет сделать

[SAB]

@Resin

наздоровье

Слова материальны. Не раздавайте своё здоровье чужим людям. !!!

[Sergey.B]

Спасибо.
Сейчас по пытаю его нельку наверное. Свободного времени не много.
Дальше отпишусь как ведёт себя.

[Sergey.B]

Всем доброго дня!
Кратко о первых испытаниях.
Работает отлично, пришлось немного подкорректировать максимальные значения по оси Х и Z. Еще пришлось поменять 12 выход на 5. Он же не может использоваться как аналоговый.
Теперь все работает супер. Следующий этап подключу преобразователь ШИМ сигнала в 24 вольта. Если вам интересно то буду дальше рассказывать как идет процесс.

[BOOM]

Не останавливайся.

[Resin]

@Sergey.B

Если вам интересно то буду дальше рассказывать как идет процесс.

естессно интересно!

[Sergey.B]

Всем доброго времени суток!
Продолжаю работать над схемой. Поставил преобразователь напряжения который выкладывал выше. Он не пошел. Нет ничего на выходе. Сделал другую. Тоже посоветовал тот же человек. Тоже не пошла. Схему приложу ниже. Также в обсуждении с автором. Он посоветовал убрать входное сопротивление 1 кОм. И о чудо все заработало как мне нужно.
Единственно на входе все равно нужно поставить сопротивление но маленькое 10 Ом. И ещё один вопрос посоветуйте как лучше. Я когда настраивал Ардуино ее записывал через USB прот зарядником. Когда подключил уже через соединение для питания теже самые 5В. Уже многие догадались Ардуино перестала выдавать на выхода 5 В. Только 3.5 В. Я понимаю что это из-за питания меньше 7В. Вот как лучше создать преобразователь напряжени примерно 9В или запитать 5В через какой нибудь контакт или 12 В автомобильных напрямую. Там же от7 до 12. Но боюсь 12В пускать напрямую оно же там скачет до 14В. Вдруг не выдержит. Кто нибудь испытавал так?

[Sergey.B]

[Sergey.B]

@Sergey.B

Ардуино ее записывал через USB прот зарядником

Ее записывал.

[Sergey.B]

Вот автоматика сама исправляет
ЗАПИТЫВАЛ

[nik182]

@Sergey.B

Когда подключил уже через соединение для питания теже самые 5В.

Куда ты их подсоеденил? Надо было +5 GND? не Vin

[Sergey.B]

То есть этот контакт можно использовать для питания. Спасибо.

[ЕвгенийП]

@Sergey.B

Можно мне как недоученному самоучки
Void setap ()

Можно!

[andriano]

@Sergey.B

убрать входное сопротивление 1 кОм. И о чудо все заработало как мне нужно.
Единственно на входе все равно нужно поставить сопротивление но маленькое 10 Ом.

Судя по описанию, Вы пользуетесь неверной схемой.

[_ВН]

В смысле, что у него неверного? Работает и ладно, там всего 1с копейками ампер на соленоиде

[andriano]

@_ВН

В смысле, что у него неверного?

В первую очередь - словесное описание не соответствует схеме.
У а что там может быть, когда схема неизвестна, - никто не знает.

[Sergey.B]

Всем доброго дня!
На сегодня сделал 4 канала преобразователя напряжения из ШИМ сигнала в 24В. Схема именно та с сопротивлением 10 Ом. На стенде все прекрасно работает. Не знаю та не та. Но мне этого хватает. И это главное. Сейчас приступаю к процессу сборки на тракторе. Но сегодня улетаю опять на неделю. Так что новости будут позже.
Всем хорошего дня и достижений.
Конечно там будет время пообщаться. Можно начать обсуждать климат контроль. Кто что думает.
Стоит новую тему открывать или здесь продолжить.?

[andriano]

@Sergey.B

Но мне этого хватает.

@Sergey.B

Стоит новую тему открывать или здесь продолжить.?

Если Вы не собираетесь толково описывать проект (по принципу - меня и так все устраивает), то явно не стоит.
Продолжать, впрочем, тоже.

[Wizard2022]

Пишите, очень интересная тема и крутой проект. Хотелось бы почитать и видео посмотреть как всё это ездит и работает

Я в свое время построил 4 трактора и радиоуправляемый опрыскиватель,тракторы с гидравликой, но трансмиссия классическая.

У вас просто суперский проект.

Мечтаю построить могучего агроробота, ваш проект натолкнул на мысль использовать возможно гидропривод.

[Sergey.B]

@andriano

толково описывать проект

Куда подробнее. Я выкладываю все схемы и задумки. В плане того что вы сказали что схема не то. Я не знаю. Конечно пока не испытал именно на рабочем не могу сказать на 100 прцентов. Я же пишу на стенде работает как нужно. Схему я выложил и даже то ,что вместо 1 кОм использовал 10 Ом тоже рассказал. Можно по конкретнее что значит ваше недовольство?