Кто пробовал другое ядро для STM32F103C?
Я только на нем сижу.
Понятно! Генератор от DIMAX под ним компилируется?
Ссылку дай на код который надо откомпилировать. Попробую.
Лучше уже правленый код под стандартные библиотеки, размещу:
/* Генератор с регулируемой частотой v3.0 (C)Dimax
https://arduino.ru/forum/proekty/generator-s-reguliruemoei-chastotoi-na-arduino#comment-296530 */
#define pwm2_polar 0 //полярность выхода PWM2
#define paper 0x000000 // цвет фона экрана
//#include <Adafruit_GFX_AS.h> // Core graphics library
#include <Adafruit_GFX.h> // Core graphics library
#include <Adafruit_ST7735.h> // Hardware-specific library
#include <Adafruit_ST7789.h>
#include <SPI.h>
#define TFT_CS PB12
#define TFT_DC PB11
#define TFT_RST PB10
// SPI2
#define TFT_MOSI PB15
#define TFT_MISO PB14
#define TFT_SCLK PB13
float s = 1.85; // Коэфф. пропорциональности вывода на дисплей
// Adafruit_ST7735 tft = Adafruit_ST7735(PB12, PB11,PB10);
Adafruit_ST7789 tft = Adafruit_ST7789( TFT_CS /*PB12*/,TFT_DC /*PB11*/,TFT_RST/*PB10*/);
// Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST);
volatile int enc_tic=0, duty_in=50, divider, mon_flag, modebit=1, tim_mode=0, mode=0;
volatile int encstep=1; //шаг изменения частоты по умолчанию
volatile float freq=1000; //частота по умолчанию
volatile float duty_out;// переменная счёта скважности
float t_hi, t_low; //переменные счёта длины импульсов
uint8_t wave[512]; //массив для DDS синтеза
byte sine_logo[]={25,27,28,30,31,33,34,36,37,38,40,41,42,43,
44,45,46,47,48,48,49,49,50,50,50,50,50,50,50,49,49,48,48,47,
46,45,44,43,42,41,40,38,37,36,34,33,31,30,28,27,25,23,22,20,
19,17,16,14,13,12,10,9,8,7,6,5,4,3,2,2,1,1,0,0,0,0,0,0,0,1,
1,2,2,3,4,5,6,7,8,9,10,12,13,14,16,17,19,20,22,23};
void setup() {
SPI.setModule(2);// выбор SPI2
delay(500);
//tft.initR(INITR_BLACKTAB); //ST7735
tft.init(240, 320); // ST7789
tft.setSPISpeed(18000000);
tft.invertDisplay(false);
tft.cp437(true); // не пропускаем 176 символ
//tft.setRotation(3);//дисплей горизонтально, контакты слева
tft.setRotation(1);//дисплей горизонтально, контакты справа
tft.fillScreen(paper);//залить цветом по умолчанию
tft.setTextWrap(0);//не переосить строки
nvic_irq_disable_all();//отключить все прерывания
systick_disable(); // отключить системный таймер
RCC_BASE->APB1ENR|= (1<<2)|(1<<1)|(1<<0); //включить тактирование tim-2,3,4
RCC_BASE->APB2ENR|= (1<<3)|(1<<11)|(1<<2)|(1<<0)|(1<<4);////включить тактирование port-a-b-c,tim1
AFIO_BASE->MAPR=(1<<8)|(1<<6); //tim 1 && tim 2 Partial remap
pinMode(PB0,PWM); //buzzer
pinMode(PB6,INPUT_PULLUP);//enc
pinMode(PB7,INPUT_PULLUP);//enc
pinMode(PB8,INPUT_PULLUP);//key enc
mytone(1000,50); //сигнал после старта
///////// Таймер4 -обработчик энкодера
TIMER4_BASE->CR1=(1<<2)|(1<<9);//CKD10 URS
TIMER4_BASE->CCMR1=0xf1f1; // (1<<0)|(1<<8 ); //cc1s, cc2s input mapped TI1/TI2
TIMER4_BASE->CCER=(1<<1)|(1<<5)|(1<<0)|(1<<4);//Capture/Compare 1,2 output polarity
TIMER4_BASE->SMCR=(1<<1)|(1<<0);//Encoder mode3(SMS bit)стр.407
TIMER4_BASE->CNT=0;
TIMER4_BASE->ARR=1;//ограничение счёта ( =3 для двухимпульсного энкодера)
TIMER4_BASE->SR=0; TIMER4_BASE->EGR=1;
timer_attach_interrupt(TIMER4, TIMER_UPDATE_INTERRUPT, enc_int);
TIMER4_BASE->CR1|=(1<<0);//запуск
//прерывание кнопки энкодера
attachInterrupt(PB8, key_enc_int, RISING);
timer_set();
}
void loop() {
static int old_mode_loop=-1;
if (freq > 8485) {tim_mode=1;} else {tim_mode=0;}// переключать режимы таймера
if (mode!=old_mode_loop) {
tft.fillScreen(paper); old_mode_loop=mode; mon_flag=1;
}//чистить полностью экран только при смене режимов
if (mode==7) {mon_out(); freq_meter(); }
if (mode >1 && mode<7) { mon_out(); dds_set(); } // запуск DDS режимов
if (mon_flag) { mon_out();} //в остальных ситуациях при наличии флага вывода на дисплей
}
void freq_meter(){
// ******************** счётчик импульсов ********************
pinMode(PA15,INPUT_PULLDOWN); // вход частотометра
uint32_t imp_long,imp_hi;//переменные измерения длины такта
__asm volatile( "cpsid i" );
/// Timer2 счёт младших 16 бит
TIMER2_BASE->CR1=0;//стоп таймер
TIMER2_BASE->CCER=0; TIMER2_BASE->PSC=0; TIMER2_BASE->CNT=0;
TIMER2_BASE->CCR1=0; TIMER2_BASE->CCR2=0; TIMER2_BASE->CCR3=0;
TIMER2_BASE->CCR4=0;TIMER2_BASE->PSC=0;TIMER2_BASE->SR=0;
TIMER2_BASE->CCMR2=0;
TIMER2_BASE->CR2=1<<5; //MMS:010 управление подчинённым в режиме "Update"
TIMER2_BASE->SMCR= (1<<14);// ECE & TS:000 режим 2 внешнего тактирования & разрешение работы от таймера1
TIMER2_BASE->ARR=65535; //считать до максимума
TIMER2_BASE->EGR=1; //перечитать регистры.
TIMER2_BASE->CR1|=(1<<0);//start timer2
/// Timer3 счёт старших 16 бит
TIMER3_BASE->CR1=1<<0;//стоп таймер
TIMER3_BASE->CCER=0; TIMER3_BASE->PSC=0; TIMER3_BASE->CNT=0;
TIMER3_BASE->CCR1=0; TIMER3_BASE->CCR2=0; TIMER3_BASE->CCR3=0;
TIMER3_BASE->CCR4=0;TIMER3_BASE->PSC=0;TIMER3_BASE->SR=0;TIMER3_BASE->CR2=0;
TIMER3_BASE->CCMR1=0;
TIMER3_BASE->SMCR=(1<<2)|(1<<1)|(1<<0)|(1<<4);//SMS:111 && TS:001 такт брать от 2-го таймера
TIMER3_BASE->ARR=65535; //считать до
TIMER3_BASE->EGR=1; //перечитать регистры.
TIMER3_BASE->CR1|=(1<<0);//start timer3
/// настройка времени разрешения на таймере1 для таймера2
TIMER1_BASE->CR1=(1<<3)|(1<<2);//один импульс, без прерываний
TIMER1_BASE->CNT=0;
TIMER1_BASE->CR2=(1<<4); //MMS:001 сигнал разрешения работы другим таймерам
TIMER1_BASE->CCER=0;// отключить выходы таймера на физ ноги
TIMER1_BASE->PSC=1999; // 72000000/20000= 36000кГц тактовая таймера
TIMER1_BASE->ARR=35999;//считать до 36000 (1секунда)
TIMER1_BASE->EGR=1; //перечитать регистры.
TIMER1_BASE->CR1|=(1<<0);
__asm volatile( "cpsie i" );
while (TIMER1_BASE->CR1&1) {asm volatile("nop"); if(mon_flag) {return;} }
freq= TIMER3_BASE->CNT<<16 | TIMER2_BASE->CNT ;
if (freq>1E6){ t_low=0;t_hi=0; duty_out=50;return;} //выйти если freq больше мегагерца
// Перенастройка таймера 2 в режии измерения длительности импульса и скважности
divider=1;
while ((72E6/divider/((freq>0)? freq : 1 )) > 65000) {divider++;}
__asm volatile( "cpsid i" );
TIMER2_BASE->CR1=0;//стоп таймер
TIMER2_BASE->CCER=0; TIMER2_BASE->PSC=0; TIMER2_BASE->CNT=0;
TIMER2_BASE->CCR1=0; TIMER2_BASE->CCR2=0; TIMER2_BASE->CCR3=0;
TIMER2_BASE->CCR4=0;TIMER2_BASE->PSC=0;TIMER2_BASE->SR=0;
TIMER2_BASE->CCMR2=0;
TIMER2_BASE->CR2=0;
TIMER2_BASE->PSC= divider-1;
TIMER2_BASE->SMCR=(1<<4)|(1<<6)|(1<<2);// TS:101 SMS:100 вход TI1FP1 , Режим сброса
TIMER2_BASE->CCMR1=(1<<0)|(1<<9);//CC1 input,mapped on TI1, CC2 input,mapped on TI1
TIMER2_BASE->CCER=(1<<5)|(1<<0)|(1<<4);//cc1-Hi,cc2-lo
TIMER2_BASE->EGR=1; //перечитать регистры.
TIMER2_BASE->CR1=(1<<0);
__asm volatile( "cpsie i" );
while( (TIMER2_BASE->SR&0x65F)!=0x65F) {asm volatile("nop"); if(mon_flag) {return;} }
TIMER2_BASE->CR1=0;// стоп таймер
imp_long=(uint32_t) ((TIMER2_BASE->CCR1)*divider);
imp_hi=(uint32_t) ((TIMER2_BASE->CCR2)*divider);
if (freq <1000){ freq=72E6 /imp_long;} //если freq Менее 1кГц то использовать данные второго НЧ-измерения частоты
duty_out= (float) imp_hi / (imp_long / 100.0) ;
t_low= (imp_long-imp_hi) /72.0 ;
t_hi= imp_hi /72.0;
mon_flag=1;
} //END freq meter
///////////////////////////////////////////////////////////////////////////
/////////*********** ВЫВОД НА ДИСПЛЕЙ************//////////////////////////
///////////////////////////////////////////////////////////////////////////
void mon_out(){
char mybuf[10]; float freq_out;
//************** Вывод первой строчки*****************************
tft.setCursor(0, 0); // вперёд, вниз
tft.setTextColor(ST7735_GREEN, paper);
tft.setTextSize(2);
switch(mode){
case 0: tft.print(" PWM Mode "); break;
case 1: tft.print(" Duty Mode "); break;
case 2: tft.print(" Sinus DDS "); break;
case 3: tft.print(" Triangle DDS"); break;
case 4: tft.print(" Pila1 DDS "); break;
case 5: tft.print(" Pila2 DDS "); break;
case 6: tft.print(" Meandr DDS "); break;
case 7: tft.print(" Freq. meter "); break;
}
//*****************Вывод второй строчки*****************************
tft.setTextColor(ST7735_WHITE, paper);
tft.setTextSize(3); tft.setCursor(0*s, 19*s);
if (freq >=1E6) { freq_out=freq/1E6;}
else if (freq>=1E4) { freq_out=freq/1000;}
else { freq_out=freq;}
if (mode!=7 && freq <10000) { dtostrf(freq_out, 6, 0, mybuf); tft.print(mybuf); tft.print(" "); }
else {dtostrf(freq_out, 8, 3, mybuf); tft.print(mybuf);}
//********************Вывод третьей строчки*****************************
tft.setCursor(50*s, 43*s); // вперёд, вниз
tft.setTextColor(ST7735_RED,paper);
if(freq>=1E6){tft.print("MHz");}
else if (freq>=1E4){tft.print("kHz");}
else {tft.print(" Hz");}
//********************* "осциллограммы"******************************
tft.fillRect(5*3,90*s, 100*s,38*s,paper);//вправо, вниз, ширина вправо, длина вниз
tft.drawRect(0*s,67*s, 160*s,61*s,ST7735_MAGENTA);//вправо, вниз, ширина вправо, длина вниз
if (mode<2 || mode==7){
tft.drawFastVLine(5*s, 90*s, 30*s, ST7735_CYAN); // восход фронта статическая вер линия
tft.drawFastHLine(5*s, 91*s, (int)duty_out*s, ST7735_YELLOW);//длина единицы
tft.drawFastHLine(5*s, 90*s, (int)duty_out*s, ST7735_YELLOW);//паралельная линия для выделения
tft.drawFastVLine(((int)duty_out+5)*s, 91*s, 30*s, ST7735_YELLOW);// спад
tft.drawFastVLine(((int)duty_out+4)*s, 90*s, 30*s, ST7735_YELLOW);//паралельная линия для выделения
tft.drawFastVLine(105*s, 90*s, 30*s, ST7735_YELLOW);//спад конец такта статическая вер. линия
tft.drawFastVLine(104*s, 90*s, 30*s, ST7735_YELLOW);//паралельная линия для выделения
tft.drawFastHLine(((int)duty_out+5)*s, 120*s, (100*s-(int)duty_out*s), ST7735_YELLOW);//линия единицы 2-го такта
tft.drawFastHLine(((int)duty_out+5)*s, 119*s, (100*s-(int)duty_out*s), ST7735_YELLOW);//паралельная линия для выделения
}
if (mode==2){ // логотип синуса
for(uint8_t n=0; n<100; n++){tft.drawPixel(5*s+n, 73*s+sine_logo[n],ST7735_YELLOW);
} //END for
} // END if (mode==2)
else if (mode==3){// логотип треугольника
tft.drawLine(5*s,98*s,30*s,73*s,ST7735_YELLOW);
tft.drawLine(30*s,73*s,80*s,123*s,ST7735_YELLOW);
tft.drawLine(80*s,123*s,105*s,98*s,ST7735_YELLOW);
} //END mode==3
else if (mode==4){ //логотип пилы1
tft.drawLine(5*s,123*s,105*s,73*s,ST7735_YELLOW);
tft.drawFastVLine(105*s, 73*s, 50*s, ST7735_YELLOW);//спад конец такта статическая вер. линия
} //END if (mode==3)
else if (mode==5){//логотип пилы2
tft.drawFastVLine(5*s, 73*s, 50*s, ST7735_YELLOW); // восход фронта статическая вер линия
tft.drawLine(5*s,73*s,105*s,123*s,ST7735_YELLOW);
}// END if (mode==4)
else if (mode==6){ //логотип меандра
tft.drawFastVLine(5*s,73*s,25*s,ST7735_YELLOW);
tft.drawFastHLine(5*s,73*s,50*s,ST7735_YELLOW);
tft.drawFastVLine(55*s,73*s,50*s,ST7735_YELLOW);
tft.drawFastHLine(55*s,123*s,50*s,ST7735_YELLOW);
tft.drawFastVLine(105*s,98*s,25*s,ST7735_YELLOW);
}
//*********************** характеристики сигнала****************************************
tft.setCursor(5*s, 70*s); // вперёд, вниз
tft.setTextColor(ST7735_WHITE, paper);
tft.setTextSize(1);
if (mode < 2 || mode==7){
tft.print("+Width="); if (t_hi<1E3) {tft.print(t_hi); tft.print(" uS ");} else {tft.print(t_hi/1000); tft.print(" mS ");}
tft.setCursor(5*s, 80*s); // вперёд, вниз
tft.print("-Width="); if (t_low<1E3) {tft.print(t_low); tft.print(" uS ");} else {tft.print(t_low/1000); tft.print(" mS ");}
tft.setCursor(114*s, 70*s); tft.print("Duty=");
tft.setCursor(114*s, 80*s); tft.print(duty_out,0);tft.print(" % ");
} //END if (mode < 2 || mode==7)
if (mode!=7){ // выводить шаг кроме частотометра
tft.setCursor(114*s, 95*s); tft.print("Step=");
tft.setCursor(114*s, 105*s);
switch (encstep) {
case 1: tft.print(" 1"); break;
case 10: tft.print(" 10"); break;
case 100: tft.print(" 100");break;
case 1000: tft.print("1000");break;
}// END switch case
} // END if (mode!=7)
if ( freq < 1) {tft.fillRect(1*s,68*s, 158*s,59*s,paper); }
mon_flag=0;
}//END mon_out
//обработчик прерываний энкодера
void enc_int(){
if((TIMER4_BASE->CR1)&1<<4) {enc_mode(1);}
else {enc_mode(-1);}
}// END VOID
// ФУНКЦИЯ конфигурации режимов
void enc_mode(int in){
modebit= (GPIOB_BASE->IDR&0x100); //состояние кнопки. 0-нажата
if (!modebit) {
mytone(880,30); //звук переключения режимов
mode+=in;
if(mode>7){mode=7;}
if(mode<0){mode=0;}
if (mode<2){timer_set();}
if (mode==7) {freq=0;}
mon_flag=1;
return;
}
mytone(4400,10); //звук изменения частоты
switch(mode){
case 0: if (tim_mode==0) { freq+=(encstep*in); timer_set(); } else { timer_hi_set(in); } break;
case 1: duty_in+=in; if(duty_in>99){duty_in=99;} if(duty_in<1){duty_in=1;} set_duty(); calc_freq(); break;
case 7: break; // в частотометре не реагировать на вращение энкодера
default: freq+=(encstep*in); mon_flag=1; //wave режимы
// проверка на корректность запроса частоты
if (freq<0){freq=0;} if (freq>2E5) {freq=2E5;}
} //end switch case
}//end enc_mode
// обработчик кнопки энкодера
void key_enc_int(){
if(!modebit){modebit=1; mon_flag=1;return;}// если менялся режим -выйти
if (mode==1) { mytone(880,30); mode=0; mon_flag=1; ;return;} //сменить режим и выйти если были в duty mode
mytone(220,75); //звук переключения шага
switch (encstep){
case 1: encstep=10; break;
case 10: encstep=100; break;
case 100: encstep=1000; break;
case 1000: encstep=1; break;
}
mon_flag=1; //флаг вывода на дисплей
}//end
void set_duty(){
if (mode==0 && TIMER1_BASE->ARR<100){
TIMER1_BASE->CCR1=(TIMER1_BASE->ARR+1)/2 ;
duty_in=50; return;
}
TIMER1_BASE->CCR1=(TIMER1_BASE->ARR+1)*duty_in/100;
}
//ОБЩАЯ НАСТРОЙКА ТАЙМЕРА
void timer_set(){
GPIOA_BASE->CRL=0xB4444444; //PA7 alt_output
GPIOA_BASE->CRH=0x4444444B; //PA8 alt_output
TIMER1_BASE->CCMR1=(1<<6)|(1<<5)|(1<<3);//PWM mode 1
TIMER1_BASE->CCMR2=0;TIMER1_BASE->PSC=0; TIMER1_BASE->CCR2=0; TIMER1_BASE->ARR=1; TIMER1_BASE->CR1=1;
TIMER1_BASE->CCER=(1<<0)|(1<<2)|(pwm2_polar<<3);//cc1e/cc1ne enable
//TIMER1_BASE->BDTR=(1<<15)| 255 ;// dead time sample
if (freq<1){freq=0; TIMER1_BASE->CCR1=0;TIMER1_BASE->ARR= 1; mon_flag=1; return;}
if (freq>36E6) {freq=36E6;}
divider=1;
int tim_arr = 72E6/freq;
while ( (tim_arr/divider) > 65535) {divider++;}
TIMER1_BASE->PSC=divider-1;
TIMER1_BASE->ARR=(tim_arr/divider)-1;
set_duty();
calc_freq();
}
//НАСТРОЙКА ТАЙМЕРА НА ЧАСТОТАХ ВЫШЕ 8КГЦ
void timer_hi_set(int arr){
__asm volatile( "cpsid i" );
GPIOA_BASE->CRL=0xB4444444; //PA7 alt_output
GPIOA_BASE->CRH=0x4444444B; //PA8 alt_output
TIMER1_BASE->CCMR1=(1<<6)|(1<<5)|(1<<3);//PWM mode 1
TIMER1_BASE->CCER=(1<<0)|(1<<2)|(pwm2_polar<<3);//cc1e/cc1ne enable
//насильно уменьшить шаг с ростом частоты
if (TIMER1_BASE->ARR<1000 && encstep > 100) encstep=100;
if (TIMER1_BASE->ARR<100 && encstep > 10) encstep=10;
if (TIMER1_BASE->ARR<10 && encstep > 1) encstep=1;
arr*=encstep;
int icr= TIMER1_BASE->ARR-=arr;
if (icr<1) {icr=1;} if (icr>65535) {icr=65535;}
TIMER1_BASE->ARR=icr;
__asm volatile( "cpsie i" );
set_duty();
calc_freq();
}
// РАСЧЁТ ЧАСТОТЫ И ТАЙМИНГОВ В РЕЖИМАХ PWM
void calc_freq(){
uint32_t imp_long, imp_hi;
freq= 72E6/((TIMER1_BASE->ARR+1)*divider);
duty_out= (float) TIMER1_BASE->CCR1 / ((TIMER1_BASE->ARR+1) / 100.0) ;
duty_out= floorf(duty_out);
imp_long=(uint32_t) ((TIMER1_BASE->ARR+1)*divider);
imp_hi=(uint32_t) ((TIMER1_BASE->CCR1)*divider);
t_low= (imp_long-imp_hi) /72.0 ;
t_hi= imp_hi /72.0;
mon_flag=1;
}
// КОНФИГУРАЦИЯ DDS РЕЖИМОВ
void dds_set(){
static uint32_t akkum;
static byte oldmode=255;
TIMER1_BASE->CCER=0; //timer output pins disable && перечитать регистры.
GPIOA_BASE->CRL = 0x33333333;// pa0-pa7 выход
GPIOA_BASE->CRH =0x44444444; //pa8-pa15 вход
if (oldmode !=mode) {
if (mode==2) {for(uint16_t n=0; n<512; n++){wave[n]=255*(sin(TWO_PI*float(n)/512)+1)/2 ;}}// синус
else if (mode==3){ for(uint16_t n=0; n<512; n++){if (n<256){ wave[n]=n;} else {wave[n]=(511-n);}}}//треугол
else if (mode==4){ for(uint16_t n=0; n<512; n++){ wave[n]=(n>>1);}} //пила1
else if (mode==5){ for(uint16_t n=0; n<512; n++){ wave[n]=((~n)>>1);}} //пила2
else if (mode==6){ for(uint16_t n=0; n<512; n++){if (n<256){ wave[n]=0;} else {wave[n]=255;}}} //меандр
oldmode=mode; }
//для пересчёта коэффициента вручную: частоту на экране * текущий множитель и разделить на фактически измеренную частоту
uint32_t dds_shag= (double)freq * 1670.1100841768461768461768461768;// шаг= частота*коэффициент
while(!mon_flag){GPIOA_BASE->ODR=wave[(akkum+=dds_shag)>>23];} //генерация DDS
GPIOA_BASE->CRL=0x44444444;// все пины в Z
}//END DDS set()
//
void mytone(int frq, int ms ){
if (mode==7){return;} //таймер в режиме частотометра занят
uint16_t psc=1; uint32_t tim_arr;
// настройка генератора звука на таймере3
tim_arr = 36E6/frq;
while ( (tim_arr/psc) > 65535) {psc++;}
__asm volatile( "cpsid i" );
TIMER2_BASE->SMCR=0;
TIMER3_BASE->CCR3=0; //обнулить регистр соответсвующий используемому выходу
TIMER3_BASE->PSC=psc-1;
TIMER3_BASE->ARR=(tim_arr/psc)-1;
TIMER3_BASE->CCMR2=(1<<5)|(1<<4);// OC3M:011
TIMER3_BASE->CCER=1<<8;//cc3e подключить аппаратную ногу
TIMER3_BASE->SMCR=(1<<2)|(1<<0)|(1<<4);//SMS:101 && TS:001 строб от 2-го таймера
TIMER3_BASE->EGR=1; //перечитать регистры.
TIMER3_BASE->CR1=1;
/// настройка выдержки времени на таймере2
psc=1;
tim_arr = 72E3 * ms;
while ( (tim_arr/psc) > 65536) {psc++;}
TIMER2_BASE->CCMR2=0;
TIMER2_BASE->CR2=0;
TIMER2_BASE->CR1=(1<<3)|(1<<2);//один импульс, без прероываний
TIMER2_BASE->CNT=0;
TIMER2_BASE->CR2=(1<<4); //MMS:001 сигнал разрешения работы другим таймерам
TIMER2_BASE->PSC=psc-1;
TIMER2_BASE->ARR=(tim_arr/psc)-1;
TIMER2_BASE->EGR=1; //перечитать регистры.
TIMER2_BASE->CR1|=(1<<0);
__asm volatile( "cpsie i" );
}
Нет.
Generator_Dimax_stm32:36:14: error: ‘class SPIClass’ has no member named ‘setModule’
36 | SPI.setModule(2);// выбор SPI2
Generator_Dimax_stm32:48:4: error: ‘nvic_irq_disable_all’ was not declared in this scope
48 | nvic_irq_disable_all();//отключить все прерывания
Generator_Dimax_stm32:49:3: error: ‘systick_disable’ was not declared in this scope
49 | systick_disable(); // отключить системный таймер
Generator_Dimax_stm32:53:15: error: ‘PWM’ was not declared in this scope; did you mean ‘PWR’?
53 | pinMode(PB0,PWM); //buzzer
| ^~~
| PWR
Generator_Dimax_stm32:59:7: error: ‘TIMER4_BASE’ was not declared in this scope; did you mean ‘TIM4_BASE’?
59 | TIMER4_BASE->CR1=(1<<2)|(1<<9);//CKD10 URS
| ^~~~~~~~~~~
| TIM4_BASE
Generator_Dimax_stm32:66:25: error: ‘TIMER4’ was not declared in this scope; did you mean ‘TIM4’?
66 | timer_attach_interrupt(TIMER4, TIMER_UPDATE_INTERRUPT, enc_int);
| ^~~~~~
| TIM4
Ну и так далее. Надо глобально переписывать.
Отрицательный результат тоже результат
Еще и не факт. что генератор будет работать нормально. Димакс вроде писал, что СТМ-овское ядро сильно медленнее
У Димы всё без ядра написано. В смысле инициализация железа на CMSYS. Так ядро роли не играет. А переписывать надо типаTIMER4_BASE на TIM4_BASE. Это привычно. Когда STM STDL на HAL меняло много пришлось переписывать. Особенно доставало регистры менять в одних и тех же названиях.
Взял тестовый скетч, чуток поправил, для проверки тоже пойдёт:
/**************************************************************************
This is a library for several Adafruit displays based on ST77* drivers.
Works with the Adafruit 1.8" TFT Breakout w/SD card
----> http://www.adafruit.com/products/358
The 1.8" TFT shield
----> https://www.adafruit.com/product/802
The 1.44" TFT breakout
----> https://www.adafruit.com/product/2088
The 1.14" TFT breakout
----> https://www.adafruit.com/product/4383
The 1.3" TFT breakout
----> https://www.adafruit.com/product/4313
The 1.54" TFT breakout
----> https://www.adafruit.com/product/3787
The 1.69" TFT breakout
----> https://www.adafruit.com/product/5206
The 2.0" TFT breakout
----> https://www.adafruit.com/product/4311
as well as Adafruit raw 1.8" TFT display
----> http://www.adafruit.com/products/618
Check out the links above for our tutorials and wiring diagrams.
These displays use SPI to communicate, 4 or 5 pins are required to
interface (RST is optional).
Adafruit invests time and resources providing this open source code,
please support Adafruit and open-source hardware by purchasing
products from Adafruit!
Written by Limor Fried/Ladyada for Adafruit Industries.
MIT license, all text above must be included in any redistribution
**************************************************************************/
#include <Adafruit_GFX.h> // Core graphics library
#include <Adafruit_ST7735.h> // Hardware-specific library for ST7735
#include <Adafruit_ST7789.h> // Hardware-specific library for ST7789
#include "FontsRus/TimesNRCyr10.h"
#include <SPI.h>
uint32_t old_millis();
#if defined(ARDUINO_FEATHER_ESP32) // Feather Huzzah32
#define HSPIs // Дисплей на HSPI )SPI1)
#if defined(HSPIs) // для ESP32 HSPI
#define TFT_CS 15 // GP13 - CS
#define TFT_RST 16 // GP14 - RESET
#define TFT_DC 17 // GP15 - A0
#define TFT_MISO 12 // GP12 - MISO (MISO, RX)
#define TFT_MOSI 13 // GP11 - SDA (MOSI, TX)
#define TFT_SCLK 14 // GP10 - SCK
#else // для ESP32 VSPI (SPI0)
#define TFT_CS 5 // GP5 - CS
#define TFT_RST 20 // GP20 - RESET
#define TFT_DC 21 // GP21 - A0
#define TFT_MISO 19 // GP19 - MISO (MISO, RX)
#define TFT_MOSI 23 // GP23 - SDA (MOSI, TX)
#define TFT_SCLK 18 // GP18 - SCK
#endif
/*
#define TFT_CS 14
#define TFT_RST 15
#define TFT_DC 32
*/
#elif defined(ESP8266)
#define TFT_CS 4
#define TFT_RST 16
#define TFT_DC 5
#elif ( defined(ARDUINO_NANO_RP2040_CONNECT) || defined(ARDUINO_RASPBERRY_PI_PICO) || defined(ARDUINO_ADAFRUIT_FEATHER_RP2040) || \
defined(ARDUINO_GENERIC_RP2040) )
// замаркировать если используем наоборот
#define SPI01 // Дисплей на SPIO1, NRF24L01 на SPI0 (выбор между SPI0 и SPI1)
#if defined(SPI01) // для RP2040 SPI1
#define TFT_CS 13 // GP13 - CS (hard - 13)
#define TFT_RST 10 // GP14 - RESET (10)
#define TFT_DC 11 // GP15 - A0 (11)
#define TFT_MISO 12 // GP12 - MISO (MISO, RX) (hard - 12)
#define TFT_MOSI 15 // GP11 - SDA (MOSI, TX) (hard - 15)
#define TFT_SCLK 14 // GP10 - SCK (hard - 14)
#else // для RP2040 SPI0
#define TFT_CS 17 //5 // GP5 - CS (hard - 17)
#define TFT_RST 20 //6 // GP6 - RESET
#define TFT_DC 21 //7 // GP7 - A0
#define TFT_MISO 16 //4 // GP4 - MISO (MISO, RX) (hard - 16)
#define TFT_MOSI 19 //3 // GP3 - SDA (MOSI, TX) (hard - 19)
#define TFT_SCLK 18 //2 // GP2 - SCK (hard - 18)
#endif
#elif (defined(_VARIANT_ARDUINO_STM32_)|| defined(_BOARD_GENERIC_STM32F103C_))
#define TFT_CS PB12
#define TFT_DC PB11
#define TFT_RST PB10
// SPI2
#define TFT_MOSI PB15
#define TFT_MISO PB14
#define TFT_SCLK PB13
#else // UNO, NANO
#define TFT_CS 10
#define TFT_RST 9
#define TFT_DC 8
#define TFT_MISO 12
#define TFT_MOSI 11
#define TFT_SCLK 13
#endif
// OPTION 1 (recommended) is to use the HARDWARE SPI pins, which are unique
// to each board and not reassignable. For Arduino Uno: MOSI = pin 11 and
// SCLK = pin 13. This is the fastest mode of operation and is required if
// using the breakout board's microSD card.
// For 1.44" and 1.8" TFT with ST7735 use:
//Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_RST);
// For 1.14", 1.3", 1.54", 1.69", 2.0" and 2.4" TFT with ST7789:
//Adafruit_ST7789 tft = Adafruit_ST7789(&SPI1,TFT_CS, TFT_DC, TFT_RST); //SPI1
Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_RST); //SPI0
//Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST); //SOFT SPI
// OPTION 2 lets you interface the display using ANY TWO or THREE PINS,
// tradeoff being that performance is not as fast as hardware SPI above.
//#define TFT_MOSI 11 // Data out
//#define TFT_SCLK 13 // Clock out
// For ST7735-based displays, we will use this call
//Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST);
// OR for the ST7789-based displays, we will use this call
//Adafruit_ST7789 tft = Adafruit_ST7789(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST);
float p = 3.1415926;
#define maxString 100 // ограничиваем строку шириной экрана
char target[maxString + 1] = "";
char *utf8rus2(char *source)
{
int i, j, k;
unsigned char n;
char m[2] = { '0', '\0' };
strcpy(target, ""); k = strlen(source); i = j = 0;
while (i < k) {
n = source[i]; i++;
if (n >= 127) {
switch (n) {
case 208: {
n = source[i]; i++;
if (n == 129) {
n = 192; // перекодируем букву Ё
break;
}
break;
}
case 209: {
n = source[i]; i++;
if (n == 145) {
n = 193; // перекодируем букву ё
break;
}
break;
}
}
}
m[0] = n; strcat(target, m);
j++; if (j >= maxString) break;
}
return target;
}
uint16_t time; // = millis();
void setup(void) {
Serial.begin(115200);
Serial.print(F("Hello! ST77xx TFT Test"));
// Use this initializer if using a 1.8" TFT screen:
// tft.initR(INITR_BLACKTAB); // Init ST7735S chip, black tab
// OR use this initializer if using a 1.8" TFT screen with offset such as WaveShare:
// tft.initR(INITR_GREENTAB); // Init ST7735S chip, green tab
// OR use this initializer (uncomment) if using a 1.44" TFT:
//tft.initR(INITR_144GREENTAB); // Init ST7735R chip, green tab
// OR use this initializer (uncomment) if using a 0.96" 160x80 TFT:
//tft.initR(INITR_MINI160x80); // Init ST7735S mini display
// OR use this initializer (uncomment) if using a 1.3" or 1.54" 240x240 TFT:
//tft.init(240, 240); // Init ST7789 240x240
// OR use this initializer (uncomment) if using a 1.69" 280x240 TFT:
//tft.init(240, 280); // Init ST7789 280x240
// OR use this initializer (uncomment) if using a 2.0" or 2.4" SPI V1.2 240x320 TFT:
SPI.setModule(2);// выбор SPI2
tft.init(240, 320); // Init ST7789 240x320
tft.setSPISpeed(18000000);
tft.invertDisplay(false);
tft.cp437(true); // не пропускаем 176 символ
// OR use this initializer (uncomment) if using a 1.14" 240x135 TFT:
//tft.init(135, 240); // Init ST7789 240x135
// OR use this initializer (uncomment) if using a 1.47" 172x320 TFT:
//tft.init(172, 320); // Init ST7789 172x320
// SPI speed defaults to SPI_DEFAULT_FREQ defined in the library, you can override it here
// Note that speed allowable depends on chip and quality of wiring, if you go too fast, you
// may end up with a black screen some times, or all the time.
tft.setSPISpeed(8000000); // установить скорость SPI
Serial.println(F("Initialized"));
// tft.setRotation(0); // разъём вверху
tft.setRotation(1); // разъём слева
// tft.setRotation(2); // разъём внизу
// tft.setRotation(3); // разъём справа
tft.invertDisplay(false);
tft.cp437(true); // не пропускаем 176 символ
}
void my_tft(void){
tft.fillScreen(ST77XX_BLACK);
time = millis() - time;
Serial.println(time, DEC);
delay(500);
// large block of text
tft.fillScreen(ST77XX_BLACK);
tft.setFont(&TimesNRCyr10pt8b);
tft.print(utf8rus2("Начали тест с русскими символами на графическом дисплее"));
delay(3000);
tft.setFont(); // выбор шрифта по умолчанию
testdrawtext("Lorem ipsum dolor sit amet, consectetur adipiscing elit. Curabitur adipiscing ante sed nibh tincidunt feugiat. Maecenas enim massa, fringilla sed malesuada et, malesuada sit amet turpis. Sed porttitor neque ut ante pretium vitae malesuada nunc bibendum. Nullam aliquet ultrices massa eu hendrerit. Ut sed nisi lorem. In vestibulum purus a tortor imperdiet posuere. ", ST77XX_WHITE);
delay(3000);
// tft print function!
tftPrintTest();
delay(4000);
// a single pixel
tft.drawPixel(tft.width() / 2, tft.height() / 2, ST77XX_GREEN);
delay(500);
// line draw test
testlines(ST77XX_YELLOW);
delay(500);
// optimized lines
testfastlines(ST77XX_RED, ST77XX_BLUE);
delay(500);
testdrawrects(ST77XX_GREEN);
delay(500);
testfillrects(ST77XX_YELLOW, ST77XX_MAGENTA);
delay(500);
tft.fillScreen(ST77XX_BLACK);
testfillcircles(10, ST77XX_BLUE);
testdrawcircles(10, ST77XX_WHITE);
delay(500);
testroundrects();
delay(500);
testtriangles();
delay(500);
mediabuttons();
delay(500);
Serial.println("done");
delay(1000);
}
void loop() {
static int r = 0;
tft.setRotation(r);
r++;
if(r==4)r=0;
my_tft();
}
void testlines(uint16_t color) {
tft.fillScreen(ST77XX_BLACK);
for (int16_t x = 0; x < tft.width(); x += 6) {
tft.drawLine(0, 0, x, tft.height() - 1, color);
delay(0);
}
for (int16_t y = 0; y < tft.height(); y += 6) {
tft.drawLine(0, 0, tft.width() - 1, y, color);
delay(0);
}
tft.fillScreen(ST77XX_BLACK);
for (int16_t x = 0; x < tft.width(); x += 6) {
tft.drawLine(tft.width() - 1, 0, x, tft.height() - 1, color);
delay(0);
}
for (int16_t y = 0; y < tft.height(); y += 6) {
tft.drawLine(tft.width() - 1, 0, 0, y, color);
delay(0);
}
tft.fillScreen(ST77XX_BLACK);
for (int16_t x = 0; x < tft.width(); x += 6) {
tft.drawLine(0, tft.height() - 1, x, 0, color);
delay(0);
}
for (int16_t y = 0; y < tft.height(); y += 6) {
tft.drawLine(0, tft.height() - 1, tft.width() - 1, y, color);
delay(0);
}
tft.fillScreen(ST77XX_BLACK);
for (int16_t x = 0; x < tft.width(); x += 6) {
tft.drawLine(tft.width() - 1, tft.height() - 1, x, 0, color);
delay(0);
}
for (int16_t y = 0; y < tft.height(); y += 6) {
tft.drawLine(tft.width() - 1, tft.height() - 1, 0, y, color);
delay(0);
}
}
void testdrawtext(char *text, uint16_t color) {
tft.setCursor(0, 0);
tft.setTextColor(color);
tft.setTextWrap(true);
tft.print(text);
}
void testfastlines(uint16_t color1, uint16_t color2) {
tft.fillScreen(ST77XX_BLACK);
for (int16_t y = 0; y < tft.height(); y += 5) {
tft.drawFastHLine(0, y, tft.width(), color1);
}
for (int16_t x = 0; x < tft.width(); x += 5) {
tft.drawFastVLine(x, 0, tft.height(), color2);
}
}
void testdrawrects(uint16_t color) {
tft.fillScreen(ST77XX_BLACK);
for (int16_t x = 0; x < tft.width(); x += 6) {
tft.drawRect(tft.width() / 2 - x / 2, tft.height() / 2 - x / 2 , x, x, color);
}
}
void testfillrects(uint16_t color1, uint16_t color2) {
tft.fillScreen(ST77XX_BLACK);
for (int16_t x = tft.width() - 1; x > 6; x -= 6) {
tft.fillRect(tft.width() / 2 - x / 2, tft.height() / 2 - x / 2 , x, x, color1);
tft.drawRect(tft.width() / 2 - x / 2, tft.height() / 2 - x / 2 , x, x, color2);
}
}
void testfillcircles(uint8_t radius, uint16_t color) {
for (int16_t x = radius; x < tft.width(); x += radius * 2) {
for (int16_t y = radius; y < tft.height(); y += radius * 2) {
tft.fillCircle(x, y, radius, color);
}
}
}
void testdrawcircles(uint8_t radius, uint16_t color) {
for (int16_t x = 0; x < tft.width() + radius; x += radius * 2) {
for (int16_t y = 0; y < tft.height() + radius; y += radius * 2) {
tft.drawCircle(x, y, radius, color);
}
}
}
void testtriangles() {
tft.fillScreen(ST77XX_BLACK);
uint16_t color = 0xF800;
int t;
int w = tft.width() / 2;
int x = tft.height() - 1;
int y = 0;
int z = tft.width();
for (t = 0 ; t <= 15; t++) {
tft.drawTriangle(w, y, y, x, z, x, color);
x -= 4;
y += 4;
z -= 4;
color += 100;
}
}
void testroundrects() {
tft.fillScreen(ST77XX_BLACK);
uint16_t color = 100;
int i;
int t;
for (t = 0 ; t <= 4; t += 1) {
int x = 0;
int y = 0;
int w = tft.width() - 2;
int h = tft.height() - 2;
for (i = 0 ; i <= 16; i += 1) {
tft.drawRoundRect(x, y, w, h, 5, color);
x += 2;
y += 3;
w -= 4;
h -= 6;
color += 1100;
}
color += 100;
}
}
void tftPrintTest() {
tft.setTextWrap(false);
tft.fillScreen(ST77XX_BLACK);
tft.setCursor(0, 30);
tft.setTextColor(ST77XX_RED);
tft.setTextSize(1);
tft.println("Hello World!");
tft.setTextColor(ST77XX_YELLOW);
tft.setTextSize(2);
tft.println("Hello World!");
tft.setTextColor(ST77XX_GREEN);
tft.setTextSize(3);
tft.println("Hello World!");
tft.setTextColor(ST77XX_BLUE);
tft.setTextSize(4);
tft.print(1234.567);
delay(1500);
tft.setCursor(0, 0);
tft.fillScreen(ST77XX_BLACK);
tft.setTextColor(ST77XX_WHITE);
tft.setTextSize(0);
tft.println("Hello World!");
tft.setTextSize(1);
tft.setTextColor(ST77XX_GREEN);
tft.print(p, 6);
tft.println(" Want pi?");
tft.println(" ");
tft.print(8675309, HEX); // print 8,675,309 out in HEX!
tft.println(" Print HEX!");
tft.println(" ");
tft.setTextColor(ST77XX_WHITE);
tft.println("Sketch has been");
tft.println("running for: ");
tft.setTextColor(ST77XX_MAGENTA);
tft.print(millis() / 1000);
tft.setTextColor(ST77XX_WHITE);
tft.print(" seconds.");
}
void mediabuttons() {
// play
tft.fillScreen(ST77XX_BLACK);
tft.fillRoundRect(25, 10, 78, 60, 8, ST77XX_WHITE);
tft.fillTriangle(42, 20, 42, 60, 90, 40, ST77XX_RED);
delay(500);
// pause
tft.fillRoundRect(25, 90, 78, 60, 8, ST77XX_WHITE);
tft.fillRoundRect(39, 98, 20, 45, 5, ST77XX_GREEN);
tft.fillRoundRect(69, 98, 20, 45, 5, ST77XX_GREEN);
delay(500);
// play color
tft.fillTriangle(42, 20, 42, 60, 90, 40, ST77XX_BLUE);
delay(50);
// pause color
tft.fillRoundRect(39, 98, 20, 45, 5, ST77XX_RED);
tft.fillRoundRect(69, 98, 20, 45, 5, ST77XX_RED);
// play color
tft.fillTriangle(42, 20, 42, 60, 90, 40, ST77XX_GREEN);
}