Ушел от delay, решил перейти на millis, но код не работает

maksmkv · 20.Январь.2023 17:33:28

Всем привет. Функция успешно работала и отображала время. Решил как все советуют уйти от delay и переделать все на millis.
Было:

void mode_display_time(){    //функция отображения времени
    int i = 0;
   
    while(i < 100) {
      now_time = tm.Hour*100 + tm.Minute; 
      
      int a = now_time/ 1000;
      int b = now_time % 1000/100;
      int c = now_time % 100/10;
      int d = now_time % 10;
      
                digitalWrite(DIGIT_1PIN,HIGH);
                digitalWrite(DIGIT_2PIN,LOW);
                digitalWrite(DIGIT_3PIN,LOW);
                digitalWrite(DIGIT_4PIN,LOW);
                show_number(a);
                delay(time_delay);
                digitalWrite(DIGIT_1PIN,LOW);
                digitalWrite(DIGIT_2PIN,HIGH);
                digitalWrite(DIGIT_3PIN,LOW);
                digitalWrite(DIGIT_4PIN,LOW);
                show_number(b);
                delay(time_delay);
                digitalWrite(DIGIT_1PIN,LOW);
                digitalWrite(DIGIT_2PIN,LOW);
                digitalWrite(DIGIT_3PIN,HIGH);
                digitalWrite(DIGIT_4PIN,LOW);
                show_number(c);
                delay(time_delay);
                digitalWrite(DIGIT_1PIN,LOW);
                digitalWrite(DIGIT_2PIN,LOW);
                digitalWrite(DIGIT_3PIN,LOW);
                digitalWrite(DIGIT_4PIN,HIGH);
                show_number(d);
                delay(time_delay);
                digitalWrite(DIGIT_1PIN,LOW);
                digitalWrite(DIGIT_2PIN,LOW);
                digitalWrite(DIGIT_3PIN,LOW);
                digitalWrite(DIGIT_4PIN,LOW);  
                i++;
     }
     display_digits_off();
     numMenu = 0;
}

Стало:

void mode_display_time(){    //функция отображения времени
    int i = 0;
   
    while(i < 100) {
      now_time = tm.Hour*100 + tm.Minute; 
      
      int a = now_time/ 1000;
      int b = now_time % 1000/100;
      int c = now_time % 100/10;
      int d = now_time % 10;
                if (millis() - previousMillis > time_delay) 
                {
                  previousMillis = millis();
                  digitalWrite(DIGIT_1PIN,HIGH);
                  digitalWrite(DIGIT_2PIN,LOW);
                  digitalWrite(DIGIT_3PIN,LOW);
                  digitalWrite(DIGIT_4PIN,LOW);
                  show_number(a);
                }
                if (millis() - previousMillis > time_delay) 
                {
                  previousMillis = millis();
                  digitalWrite(DIGIT_1PIN,LOW);
                  digitalWrite(DIGIT_2PIN,HIGH);
                  digitalWrite(DIGIT_3PIN,LOW);
                  digitalWrite(DIGIT_4PIN,LOW);  
                  show_number(b);            
                }
                
                if (millis() - previousMillis > time_delay) 
                {
                  previousMillis = millis();
                  digitalWrite(DIGIT_1PIN,LOW);
                  digitalWrite(DIGIT_2PIN,LOW);
                  digitalWrite(DIGIT_3PIN,HIGH);
                  digitalWrite(DIGIT_4PIN,LOW);
                  show_number(c);
                }
            
                if (millis() - previousMillis > time_delay) 
                {
                  previousMillis = millis();
                  digitalWrite(DIGIT_1PIN,LOW);
                  digitalWrite(DIGIT_2PIN,LOW);
                  digitalWrite(DIGIT_3PIN,LOW);
                  digitalWrite(DIGIT_4PIN,HIGH);
                  show_number(d);
                }
           
              if (millis() - previousMillis > time_delay) 
                {
                  previousMillis = millis();
                  digitalWrite(DIGIT_1PIN,LOW);
                  digitalWrite(DIGIT_2PIN,LOW);
                  digitalWrite(DIGIT_3PIN,LOW);
                  digitalWrite(DIGIT_4PIN,LOW);
                }  
                                i++;
     }
     display_digits_off();
     numMenu = 0;
}

В общем время перестало отображаться, полазил по форумам, решения как такого не нашел, кроме если делать какие-то искусственные задержки типа for или вообще serial.println добавить, ну в общем не правильно все это. Как исправить мой код, что бы работало все с миллис??? Это отображение цифр на 7 сегментом индикаторе. Если слишком гемморно, все верну обратно в delay. СПАСИБО

ua6em · 20.Январь.2023 17:35:30

нет ребята, всё не так

maksmkv · 20.Январь.2023 17:48:29

Может есть ссылка, как лучше реализовать?

sadman41 · 20.Январь.2023 17:52:46

А в чем цель этого переключения?

andriano · 20.Январь.2023 17:59:29

@maksmkv , Вы сами понимаете код который написали?
Можете объяснить, зачем употреблены те или иные конструкции?
В частности, опишите назначение строк: 11, 13, 20, 22, 30, 32, 40, 42, 50 и 52. И как эти строки взаимодействуют между собой?

b707 · 20.Январь.2023 18:08:10

в каждом случае использования миллис переменная

должна быть отдельная!

А так у вас все пять условий пересекаются.

И, кстати, где вы хоть раз запоминаете previousMillis ???

v258 · 20.Январь.2023 18:08:45

Так в лоб не получится. Раньше все делалось в один проход цикла, теперь в каждом проходе цикла (если момент настал) будет выполняться только первый if. До остальных дело не дойдет. Работа с миллисом таки отличается от работы с делеями.
Нужно делать примерно так:

завести флаг выполнения, флаг поднят - пришло время, флаг опущен - ничего не делать
завести счетчик, по значению которого будет выполняться тот или иной if
по миллису только поднимать поднимать флаг
если флаг поднят, выполнять соответствующий if, опускать флаг и увеличивать счетчик на единицу

Примерно так

Спойлер

void mode_display_time()
{ // функция отображения времени
  int i = 0;

  while (i < 100)
  {
    now_time = tm.Hour * 100 + tm.Minute;

    int a = now_time / 1000;
    int b = now_time % 1000 / 100;
    int c = now_time % 100 / 10;
    int d = now_time % 10;
    static bool flag = false;
    static byte count = 0;

    if (millis() - previousMillis > time_delay)
    {
      previousMillis = millis();
      flag = true;
    }

    if (flag)
    {
      digitalWrite(DIGIT_1PIN, LOW);
      digitalWrite(DIGIT_2PIN, LOW);
      digitalWrite(DIGIT_3PIN, LOW);
      digitalWrite(DIGIT_4PIN, LOW);

      switch (count)
      {
      case 0:
        show_number(a);
        break;
      case 1:
        show_number(b);
        break;
      case 2:
        show_number(c);
        break;
      case 3:
        show_number(d);
        break;
      case 4:
        break;
      }

      flag = false;
      if (++count >= 5)
      {
        count = 0;
      }
      i++;
    }
  }
  display_digits_off();
  numMenu = 0;
}

sadman41 · 20.Январь.2023 18:13:32

Или под if подвесить switch case.

А, сорри, я опоздал ))

maksmkv · 20.Январь.2023 19:30:59

Да честно, понять понимаю, но как говорится в голове сложилось, а на деле оказалось не так.

maksmkv · 20.Январь.2023 19:33:16

СПАСИБО, да тут совсем всё по другому. Я так полагаю о таких приемах в книгах не пишут, это только практикой доходит или так же когда-то подсказали более опытные?? СПАСИБО за реализацию. Пойду исправлять у себя. А это только часть кода, но логика уже ясна.

andycat · 20.Январь.2023 19:47:40

Не, все проще, чтоб понять цифровую логику и программирование, необходим нужный склад ума.
Как мой зять говорит : мне пофиг какой язык программировать.

maksmkv · 20.Январь.2023 19:48:59

Да вроде небольшой опыт имеется в JS, С#, DELPHI, но вот именно реализация аппаратного программирования - тут немного другое. Одно дело формочки накидать, а другое обработка кнопок, отображение символов и прочее.

ua6em · 20.Январь.2023 19:49:49

это шутка такая или пятничное?

andycat · 20.Январь.2023 19:51:08

Беда, че…
Я сам с этого начинал, ученье - свет.!

andycat · 20.Январь.2023 19:55:59

Че это?
Delphi эт обычный паскаль, очень даже норм в нашей жизни

Java маразм все перевести в объекты, ну моё мнение.
И да, для примера: мне ооп тяжело даётся, но например для других C просто невозможный язык.

ua6em · 20.Январь.2023 19:58:41

да я к тому, что никаких языков не знаю, при этом фигни практически не пишу )))
PS а если бы знал?

andycat · 20.Январь.2023 20:04:38

Тупик
Мозг должен развиваться

andriano · 20.Январь.2023 20:38:37

Да, при этом подл “практикой” нужно подразумевать следующее:
Представить себе, что микроконтроллер - это Вы, после чего попытаться выполнить имеющуюся программу. Например, если бы Вы это сделали, то самостоятельно обнаружили бы, что из всех блоков if(millis()… всегда будет выполняться только первый.

Alexey_Rem · 20.Январь.2023 21:42:25

а счетчик i будет работать как задумано?

v258 · 21.Январь.2023 03:11:53

А что с ним станется? После отработки цикла - выход из процедуры, как было в варианте ТС