Замечательный код ардуино для LED

Вот мой код. Он работает.
У меня не получается сделать в методе L0() проход по всем цветам…
Подскажите, как сделать (R++ (G++ (B++ )))

//author: Alunts Arthur Arthurovich;
//при загрузке скетча ардуино в плату отсоединяем на время загрузки RX кабель (Pin 0);
#include <Adafruit_NeoPixel.h> // подключаем библиотеку
// указываем количество пикселей в кольце и пин подключения
Adafruit_NeoPixel strip (12, 5, NEO_GRB + NEO_KHZ800);   //PIN: 5 //LED Num: 12
int ExitValue0=101;
int val;
int RR=0;
int BB=0;
int GG=0;
short flag  = 1;
short flag0 = 0;
short flag1 = 1;
short dd = 2;
int tt = 0;
int i = 0;
int ff=5;
int GGG=0;
void setup() {


  Serial.begin(9600);
  strip.setBrightness(50); //указываем яркость (max: 255);
  strip.begin();                     // инициализируем объект NeoPixel
  strip.show();                     // отключаем все пиксели на ленте
}

void L0(){
  RR=RR+ff;
  if ((RR)==(255)) {
    RR=RR+ff;
  }
  else {
    RR=0;
    GG=GG+ff;
  }

  if ((GG)==(255)) {
    GG=GG+ff;
  } 

  else {
    GG=0;
    BB=BB+ff;
  }
  
  if ((BB)==(255)) {
    BB=BB+ff;
  }
  else {
    BB=0;

  }

 // Serial.print("GGG");
  
}

void loop() {
    
  L0();

  if (i < 3) {
    
    
    strip.clear();    
    
    strip.setPixelColor(i, strip.Color(RR,GG,BB));
    strip.setPixelColor(i + 3, strip.Color(RR,GG,BB));
    strip.setPixelColor(i + 6, strip.Color(RR,GG,BB));
    strip.setPixelColor(i + 9, strip.Color(RR,GG,BB));
   
    strip.show();
 
    i++;

    //if(flag0==1){
    delay(tt);
   // flag0=0;
   // }
  }
  else {
    i = 0;

    strip.show();
  }
  if (flag == 1) {
    tt = tt + dd;
  }
  if (flag == 0) {
    tt = tt - dd;
  }
  if (tt >= 100) {
    flag = 0;
  }
  if (tt == 0) {
    flag = 1;
  }
  
strip.show();
  //Serial.println(III);




}

А Вы сами-то понимаете, что тут написано? Вот прям построчно?
По-моему какая-то ерунда получается…

Смотрим:
В первой строке к значению RR прибавляется шаг ff. Если значение RR равно 255 - еще раз прибавляем ff, а если нет (RR не равно 255) - сбрасываем RR в ноль.

И что получается? Достигнет ли RR когда-нибудь 255? - да не в жизнь

Местами поменяй.

Хотя работать, как ты хочешь всë равно не будет.

Добрые люди обычно так делают

constexpr uint8_t MIN_COLOR_VALUE = 0;
constexpr uint8_t MAX_COLOR_VALUE = 255;

uint8_t GetPredColor(const uint8_t AColor, const uint8_t AStep) {
	if (AColor > AStep)
		return AColor - AStep;
	else
		return MIN_COLOR_VALUE;
}

uint8_t GetNextColor(const uint8_t AColor, const uint8_t AStep) {
	if (AColor < (MAX_COLOR_VALUE - AStep))
		return AColor + AStep;
	else
		return MAX_COLOR_VALUE;
}

если бы только это…
В этом коде сплошная каша.. видимо автор вообще не понимает, как это работает.

1 лайк

С познаниями тс, больше выглядит, как издëвка.

Покрутил в пеинте цветовой круг, там такая таблица переходов:

T 0 1 2 3 4 5
R 255 255 0 0 0 255
G 0 255 255 255 0 0
B 0 0 0 255 255 255
Легко заметить 6 временных циклов (смотрим переходы по Т), в кольце (Ваш вариант). К примеру в первом цикле (0-1) надо только G наращивать 0-255, сохраняя постоянными R,B. В общем пишите 6 for(){} и смотрите что получилось. Кольца преследуют вас очень долго :slight_smile:
…если ни бум, бум стесняться не надо, поглумятся, но помогут…наверное.

Не нашел похожих тем с текущим и предыдущим никами ТС. Если было, дайте ссылку

Я чисто ассоциативно, по памяти. Ну он не признаётся :)…значит не он. Я запомнил, потому что чудной он товарищ на общение. Замечательный код одним словом.

А что говорит автор кода? Обращались?

Так он не ответил ничего.

Что интересно, я уже создавал такую же тему на этом форуме и решение даже выложил :grinning_face:

В простонародии это называется “алгоритм непрерывного спектра”.)

А самое забавное, что библиотеке, что использует ТС, есть готовый пример strandtest_wheel, где евонная хотелка присутствует :grinning_face:

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
  #include <avr/power.h>
#endif

#define PIN 6

// Parameter 1 = number of pixels in strip
// Parameter 2 = Arduino pin number (most are valid)
// Parameter 3 = pixel type flags, add together as needed:
//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
//   NEO_GRB     Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB     Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
//   NEO_RGBW    Pixels are wired for RGBW bitstream (NeoPixel RGBW products)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(60, PIN, NEO_GRB + NEO_KHZ800);

// IMPORTANT: To reduce NeoPixel burnout risk, add 1000 uF capacitor across
// pixel power leads, add 300 - 500 Ohm resistor on first pixel's data input
// and minimize distance between Arduino and first pixel.  Avoid connecting
// on a live circuit...if you must, connect GND first.

void setup() {
  // This is for Trinket 5V 16MHz, you can remove these three lines if you are not using a Trinket
  #if defined (__AVR_ATtiny85__)
    if (F_CPU == 16000000) clock_prescale_set(clock_div_1);
  #endif
  // End of trinket special code

  strip.begin();
  strip.setBrightness(50);
  strip.show(); // Initialize all pixels to 'off'
}

void loop() {
  // Some example procedures showing how to display to the pixels:
  colorWipe(strip.Color(255, 0, 0), 50); // Red
  colorWipe(strip.Color(0, 255, 0), 50); // Green
  colorWipe(strip.Color(0, 0, 255), 50); // Blue
//colorWipe(strip.Color(0, 0, 0, 255), 50); // White RGBW
  // Send a theater pixel chase in...
  theaterChase(strip.Color(127, 127, 127), 50); // White
  theaterChase(strip.Color(127, 0, 0), 50); // Red
  theaterChase(strip.Color(0, 0, 127), 50); // Blue

  rainbow(20);
  rainbowCycle(20);
  theaterChaseRainbow(50);
}

// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
  for(uint16_t i=0; i<strip.numPixels(); i++) {
    strip.setPixelColor(i, c);
    strip.show();
    delay(wait);
  }
}

void rainbow(uint8_t wait) {
  uint16_t i, j;

  for(j=0; j<256; j++) {
    for(i=0; i<strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel((i+j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
  uint16_t i, j;

  for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel
    for(i=0; i< strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

//Theatre-style crawling lights.
void theaterChase(uint32_t c, uint8_t wait) {
  for (int j=0; j<10; j++) {  //do 10 cycles of chasing
    for (int q=0; q < 3; q++) {
      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
        strip.setPixelColor(i+q, c);    //turn every third pixel on
      }
      strip.show();

      delay(wait);

      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
        strip.setPixelColor(i+q, 0);        //turn every third pixel off
      }
    }
  }
}

//Theatre-style crawling lights with rainbow effect
void theaterChaseRainbow(uint8_t wait) {
  for (int j=0; j < 256; j++) {     // cycle all 256 colors in the wheel
    for (int q=0; q < 3; q++) {
      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
        strip.setPixelColor(i+q, Wheel( (i+j) % 255));    //turn every third pixel on
      }
      strip.show();

      delay(wait);

      for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
        strip.setPixelColor(i+q, 0);        //turn every third pixel off
      }
    }
  }
}

// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
  WheelPos = 255 - WheelPos;
  if(WheelPos < 85) {
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  if(WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
  WheelPos -= 170;
  return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}
1 лайк

Почему не будет?

В исполнении ТС - не будет :slight_smile:

(сообщение удалено автором)

нихрена не получилось